1 REM *********************************
2 REM *         'AUTO MENU'           *
3 REM * READS DIRECTORY & AUTO LOADS  *
4 REM * PROGRAM SELECTED BY THE USER  *
5 REM *             BY                *
6 REM * JOE W. ROCKE          7/27/84 *
7 REM *********************************
10 POKE53280,0:POKE53281,0
20 DIM N$(100):CX=54272:PRINT "[147]"
30 PRINT"[147][129]"
40 X$="                                       "
50 FORX=1TO5:PRINTX$:NEXT
60 PRINT"":PRINT CHR$(117);
70 FOR X=1 TO 38:PRINTCHR$(100);:NEXT
80 PRINTCHR$(105);:FOR X=1 TO 5
90 PRINTCHR$(103)SPC(38)CHR$(104)" "CHR$(157);:NEXT
100 PRINTCHR$(106);:FOR X=1 TO 38:PRINTCHR$(102);:NEXT:PRINTCHR$(107)
110 PRINT""TAB(14)"* AUTO MENU *"
120 PRINTTAB(12)"[158]READING DIRECTORY"
129 REM --- READ DISK DIRECTORY ---
130 OPEN1,8,0,"$"
140 GET#1,B$:IFST<>0THEN260
149 REM --- LINE 150 LIMITS TO 26 FILES ---
150 IFF>=27THEN260
160 IFB$<>CHR$(34)THEN140
170 N$="":PRINT"":POKE 214,8:PRINT
180 GET#1,B$:IFB$<>CHR$(34)THENN$=N$+B$:GOTO180
190 GET#1,B$:IFB$=CHR$(32)THEN190
199 REM -- FOLLOWING LINES SKIP THE LOADING FILES --
200 IFN$="BOOT"THENF=F-1:GOTO240
210 IFN$="AUTO MENU"THENF=F-1:GOTO240
220 IFLEFT$(N$,1)=" "THENF=F-1:GOTO240
230 N$(F)=" "+N$
240 GET#1,B$:IFB$<>""THEN240
250 IFST=0THENF=F+1:GOTO140
260 CLOSE1
269 REM - PRINT FIRST COLUMN OF NAMES -
270 FORE=1TOF/2:PRINT"[153]"CHR$(64+E)""N$(E):NEXT
280 PRINT"":POKE214,8:PRINT
289 REM -- THEN 2ND COLUMN OF NAMES ---
290 FORE=F/2+1TOF:PRINTSPC(20)"[153]"CHR$(64+E)""N$(E):NEXT
300 PRINT""
310 PRINTTAB(12)"[158] PRESS LETTER KEY "
320 PRINTTAB(5)"TO AUTO LOAD PROGRAM SELECTED"
330 GETM$:IFM$=""THEN 330
340 IFM$=CHR$(13)THENRUN
350 IFM$<"A"ORM$>CHR$(64+F)THEN330
351 IFM$="G"GOTO391
360 P=ASC(M$)-64:PRINT"[147]"
370 IFLEN(N$(P))>12THENN$(P)=LEFT$(N$(P),12)+"*"
380 N$(P)=MID$(N$(P),2,LEN(N$(P)))
390 PRINT"LOAD"CHR$(34)N$(P)CHR$(34)",8,1[145][145][145]":GOTO460
391 P=ASC(M$)-64:PRINT"[147]"
392 IFLEN(N$(P))>12THENN$(P)=LEFT$(N$(P),12)+"*"
393 N$(P)=MID$(N$(P),2,LEN(N$(P)))
394 PRINT"LOAD"CHR$(34)N$(P)CHR$(34)",8[145][145][145]"
400 REM *******************************
410 REM * IF YOU KNOW THE PGM IS 'ML' *
420 REM * THE EXAMPLE BELOW WILL LOAD *
430 REM * AND FILE & RUN IT. EXAMPLES *
440 REM * (3) ARE SHOWN BELOW.        *
450 REM *******************************
460 IFLEFT$(N$(P),4)="TOOL"THENA$="SYS64738"+CHR$(13):GOTO500
470 IFLEFT$(N$(P),6)="SPRITE"THENA$="SYS49152"+CHR$(13):GOTO500
480 IFLEFT$(N$(P),5)="ULTRA"THENA$="SYS49152"+CHR$(13):GOTO500
490 A$="RUN"+CHR$(13)
500 POKE631,13:FORB=1TOLEN(A$):POKE631+B,ASC(MID$(A$,B,1)):NEXT:POKE198,10
510 NEW